lt: Wasm text instruction

Try it

(module
  (import "env" "log_bool" (func $log_bool (param i32)))
  (func $main
    ;; load 10.1 and 3.5 onto the stack
    f32.const 10.1
    f32.const 3.5

    f32.lt ;; check if 10.1 is less than 3.5
    call $log_bool ;; log the result
  )
  (start $main)
)

const url = "{%wasm-url%}";

function log_bool(value) {
  console.log(Boolean(value));
  // Expected output: false
}

await WebAssembly.instantiateStreaming(fetch(url), {
  env: { log_bool },
});

Syntax

value_type.lt

value_type

The type of value the instruction is being run on. The following types support lt:

• f32
• f64
• v128 interpretations:
  • f32x4
  • f64x2

lt

The lt instruction. Must always be included after the value_type and a period (.).

Type

[input1, input2] -> [output]

input1

The first input value.

input2

The second input value.

output

The output value, which will be an integer type.

For a non-SIMD lt, the inputs will be basic numeric values such as 3.0 or 3.5. If the first input is less than the second input, 1 will be pushed on to the stack as an output, otherwise 0 will be pushed on to the stack.

For a SIMD lt, the inputs will be v128 value interpretations, for example f32x4 2.0 30 86.9 120. Each lane of the output pushed to the stack is a 1 or 0 indicating whether the corresponding lane of the first input value is less than the corresponding lane of the second input value.

Binary encoding

Examples

SIMD lt example

In this example, we demonstrate using lt to test whether one SIMD lane value is less than the same lane value in another SIMD value.

JavaScript

In our script, we grab a reference to a <p> element that we will output our result to, then define an object for import into Wasm containing a single function that writes a value to the output <p>. We then compile and instantiate our Wasm module using the WebAssembly.instantiateStreaming() method, importing the object in the process.

<p></p>

const outputElem = document.querySelector("p");

const obj = {
  output(val) {
    outputElem.textContent += val;
  },
};

WebAssembly.instantiateStreaming(fetch("{%wasm-url%}"), {
  obj,
});

Wasm

In our Wasm module, we first import the JavaScript output() function, making sure to declare that it has an i32 parameter. We then declare two SIMD f32x4 values, then check whether the first one's lane values are less than the second using f32x4.lt. Finally we extract the value stored in lane 3 of the output value using the extract_lane instruction, and output it to the DOM by calling the imported output() function.

(module
  ;; Import output function
  (import "obj" "output" (func $output (param i32)))

  (func $main
    ;; load two SIMD values onto the stack
    v128.const f32x4 20 12 15 102
    v128.const f32x4 20 12 15 100

    ;; check whether the first value is less than the second
    f32x4.lt
    i32x4.extract_lane 3 ;; Extract a value from the result

    call $output
  )

  (start $main)
)

Result

The output is as follows:

The result is 0 because the value stored in lane 3 of the first input value is not less than the value stored in lane 3 of the second input value.

See also

• lt_s
• lt_u