size: Wasm table instruction

Probieren Sie es aus

(module
  ;; table with 0 function slots
  (table $my_table 0 funcref)

  (func (export "run") (result i32)
    ;; Grow the table by 1, setting the initial values to null.
    (table.grow $my_table
      ref.null func
      (i32.const 1)
    )
    (drop)

    (table.size $my_table)
  )
)

WebAssembly.instantiateStreaming(fetch("{%wasm-url%}")).then((result) => {
  const value = result.instance.exports.run();
  console.log(value);
});

Syntax

table.size identifier

table.size

Der Anweisungstyp table.size. Muss immer zuerst angegeben werden.

identifier Optional

Der Bezeichner für die Tabelle, deren Größe Sie abrufen möchten. Dies kann einer der folgenden sein:

name

Ein beim Erstellen der Tabelle gesetzter Name. Dieser muss mit einem $-Symbol beginnen, zum Beispiel $my_table.

index

Die Indexnummer der Tabelle, zum Beispiel 0 für die erste Tabelle im Wasm-Skript, 1 für die zweite, usw.

Wenn der identifier weggelassen wird, wird standardmäßig 0 angenommen.

Typ

[] -> [length]

Länge

Ein i32, der der aktuellen Anzahl von Elementen in der Tabelle entspricht.

Opcodes

Beschreibung

table.size wird verwendet, um die Größe einer Tabelle zurückzugeben.

Die Größe einer Wasm-Tabelle kann über JavaScript mit der table.length Eigenschaft abgerufen werden.

Beispiele

Beobachtung von Zunahmen der Tabellengröße

Dieses Beispiel zeigt, wie man eine Tabelle erstellt und ihre Größe beobachtet, während die Tabelle mittels table.size wächst.

JavaScript

In unserem Skript beginnen wir damit, eine Referenz auf ein <p>-Element zu erhalten, an das wir die Ergebnisse ausgeben werden. Wir definieren dann ein obj-Objekt, das eine Funktion namens output() enthält, die einen gegebenen Wert zum textContent eines gegebenen Elements hinzufügt.

Wir kompilieren und instanziieren dann unser Wasm-Modul mithilfe der Methode WebAssembly.instantiateStreaming() und importieren dabei das obj-Objekt.

Wenn das Ergebnis zurückgegeben wird, rufen wir die exportierte Wasm-run()-Funktion auf dem WebAssembly-Instance-exports-Objekt auf und übergeben das outputElem-Element als Parameter.

<p></p>

const outputElem = document.querySelector("p");

const obj = {
  output(elem, val) {
    elem.textContent += `${val} `;
  },
};

WebAssembly.instantiateStreaming(fetch("{%wasm-url%}"), {
  obj,
}).then((result) => {
  value = result.instance.exports.run(outputElem);
});

Wasm

In unserem Wasm-Modul importieren wir zuerst die JavaScript-Funktion output(), wobei wir sicherstellen, dass sie zwei Parameter hat: einen externref und einen i32.

Als nächstes definieren wir eine table, die Funktionsreferenzen speichert (daher wird funcref angegeben) und leer ist.

Schließlich exportieren wir die run()-Funktion, die einen externref namens $elem als Parameter übernimmt. Im Funktionskörper:

• Verwenden wir table.grow, um die Tabellengröße um 1 mit einem anfänglichen ref.null-Wert zu vergrößern.
• Rufen wir die importierte $output-Funktion auf und übergeben ihr als Parameter den übergebenen $elem externref in die output()-Funktion und den Rückgabewert der table.size-Anweisung. Dies führt dazu, dass die Tabellengröße im DOM ausgegeben wird.
• Wiederholen wir die letzten zwei Schritte, was dazu führt, dass die Tabelle um ein weiteres Element vergrößert wird und die Größe erneut im DOM ausgegeben wird.

(module
  ;; Import output function
  (import "obj" "output" (func $output (param externref) (param i32)))

  ;; Define an initially empty table of funcrefs
  (table 0 funcref)

  (func (export "run") (param $elem externref)
    ;; Grow the table by 1, setting the initial values to null.
    (table.grow
      ref.null func
      (i32.const 1)
    )
    (drop)

    ;; Call the output function, to output the table size to the DOM
    (call $output
      (local.get $elem)
      (table.size)
    )

    ;; Grow the table by 1, setting the initial values to null.
    (table.grow
      ref.null func
      (i32.const 1)
    )
    (drop)

    ;; Call the output function, to output the table size to the DOM
    (call $output
      (local.get $elem)
      (table.size)
    )
  )
)

Ergebnis

Die Ausgabe ist wie folgt:

Dies ist sinnvoll, da jedes Mal, wenn die output()-Funktion aus dem Wasm-Modul aufgerufen wird, der in sie als zweiter Parameter eingehende Wert in unserem Ergebnis-<p> im DOM ausgegeben wird. Jeder Wert ist die Tabellengröße zu jedem Zeitpunkt — 1 bzw. 2.

Spezifikationen

Browser-Kompatibilität

Siehe auch

• table.grow
• table.set